Wie kann ich mithilfe der Befehlszeile feststellen, ob mein System Windows 10 ist?

Gibt es einen Befehl, um festzustellen, ob ich auf einem Windows 10-System arbeite?

Sie können wmic verwenden.

Der folgende Befehl gibt die Windows-Version zurück.

wmic os get Caption | findstr /v Caption

Beispielausgabe:

F:\test>wmic os get Caption | findstr /v Caption
Microsoft Windows 7 Home Premium

Wenn Sie etwas mehr Informationen wünschen, können Sie die folgende Batch-Datei (GetOS.cmd) verwenden, die abgerufen und angezeigt wird:

• Betriebssystemversion
• Service Pack Major Version
• Architektur (64 oder 32 Bit)

@echo off
setlocal
setlocal enabledelayedexpansion
set _os=
set _sp=
rem use findstr to strip blank lines from wmic output
rem get OS
for /f "usebackq skip=1 tokens=3" %%i in (`wmic os get caption ^| findstr /r /v "^$"`) do (
  set "_os=%%i"
  )
rem get Service Pack
for /f "usebackq skip=1 tokens=*" %%i in (`wmic os get ServicePackMajorVersion ^| findstr /r /v "^$"`) do (
  set "_sp=%%i"
  )
rem get Architecture
for /f "usebackq skip=1 tokens=*" %%i in (`wmic OS get OSArchitecture ^| findstr /r /v "^$"`) do (
  set "_bits=%%i"
  )
echo Operating System Version: %_os%
echo Service Pack Major Version: %_sp%
echo Architecture: %_bits%
endlocal

Die Betriebssystemversion ist in %_os gespeichert, die Service Pack-Hauptversion in %_sp% und die Architektur in %_bits%.

Anmerkungen:

• Nicht vollständig getestet, da ich nicht alle Betriebssystem- und Service Pack-Kombinationen zum Testen habe.

• Der Befehl for ruft nur den dritten Teil (Token) des Betriebssystems ab. Dies funktioniert für die Desktop-Versionen (wenn Sie Server 2008 von anderen Versionen unterscheiden möchten, müssen Sie eine andere Lösung finden).

• %_os wird auf einen der folgenden Werte gesetzt: Server, Vista, 7, 8, 8.1 oder 10.

Beispielausgabe:

F:\test>GetOS
Operating System Version: 7
Service Pack Major Version: 1
Architecture: 64-bit

F:\test>

Weitere Lektüre

• Ein A-Z-Index der Windows CMD-Befehlszeile - Eine hervorragende Referenz für alle Dinge, die mit der Windows-Befehlszeile zu tun haben.
• findstr - Suche nach Strings in Dateien.
• für/f - Schleifenbefehl gegen die Ergebnisse eines anderen Befehls.
• if - Führen Sie unter bestimmten Bedingungen einen Befehl aus.
• wmic - Windows-Verwaltungsinstrumentationsbefehl.