wake-up-neo.com

Kann eine Windows-Batchdatei ihren eigenen Dateinamen ermitteln?

Kann eine Windows-Batchdatei ihren eigenen Dateinamen ermitteln?

Wenn ich zum Beispiel die Batchdatei C:\Temp\myScript.bat ausführen kann, gibt es in myScript.bat einen Befehl, der die Zeichenfolge "myScript.bat" bestimmen kann?

78
djangofan

Ja. 

Verwenden Sie die spezielle Variable %0, um den Pfad zur aktuellen Datei abzurufen. 

Schreiben Sie %~n0, um nur den Dateinamen ohne die Erweiterung zu erhalten.

Schreiben Sie %~n0%~x0, um den Dateinamen und die Erweiterung zu erhalten.

Es ist auch möglich, %~nx0 zu schreiben, um den Dateinamen und die Erweiterung zu erhalten.

115
SLaks

Sie können den Dateinamen abrufen, aber Sie können auch den vollständigen Pfad abrufen, je nachdem, was Sie zwischen "% ~" und "0" angeben. Wählen Sie aus

d -- drive
p -- path
n -- file name
x -- extension
f -- full path

Zum Beispiel, aus c:\tmp\foo.bat gibt %~nx0 "foo.bat", während %~dpnx0 "c:\tmp\foo.bat" gibt. Beachten Sie, dass die Teile immer in kanonischer Reihenfolge zusammengestellt werden. Wenn Sie also niedlich werden und %~xnpd0 versuchen, sollten Sie dies tun immer noch Holen Sie sich "c:\tmp\foo.bat"

30
JustJeff

Mit dem folgenden Skript, basierend auf der Antwort von SLaks, habe ich festgestellt, dass die richtige Antwort lautet:

echo The name of this file is: %~n0%~x0
echo The name of this file is: %~nx0

Und hier ist mein Testskript:

@echo off
echo %0
echo %~0
echo %n0
echo %x0
echo %~n0
echo %dp0
echo %~dp0
pause

Was ich interessant finde, ist, dass% nx0 nicht funktioniert, da wir wissen, dass das Zeichen '~' normalerweise verwendet wird, um Anführungszeichen von einer Variablen zu entfernen.

29
djangofan

Beachten Sie, dass 0 ein Sonderfall von Parameternummern in einer Batchdatei ist, wobei 0 diese Datei wie in der Befehlszeile angegeben bedeutet.

Wenn die Datei myfile.bat ist, können Sie sie auf verschiedene Weise wie folgt aufrufen. Jede davon würde Ihnen eine andere -Ausgabe von der Verwendung von% 0 oder% ~ 0 geben:

meine Datei

myfile.bat

mydir\myfile.bat

c:\mydir\myfile.bat

"c:\mydir\myfile.bat"

Alle oben genannten sind rechtlich zulässig, wenn Sie es vom richtigen relativen Ort in das Verzeichnis aufrufen, in dem es existiert. % ~ 0 entfernt die Anführungszeichen aus dem letzten Beispiel, während% 0 dies nicht tut.

Da diese Ergebnisse alle zu unterschiedlichen Ergebnissen führen, ist es unwahrscheinlich, dass% 0 und% ~ 0 das sind, was Sie tatsächlich verwenden möchten.

Hier ist eine Batchdatei zur Veranschaulichung:

@echo Full path and filename: %~f0
@echo Drive: %~d0
@echo Path: %~p0
@echo Drive and path: %~dp0
@echo Filename without extension: %~n0
@echo Filename with    extension: %~nx0
@echo Extension: %~x0
@echo Filename as given on command line: %0
@echo Filename as given on command line minus quotes: %~0
@REM Build from parts
@SETLOCAL
@SET drv=%~d0
@SET pth=%~p0
@SET fpath=%~dp0
@SET fname=%~n0
@SET ext=%~x0
@echo Simply Constructed name: %fpath%%fname%%ext%
@echo Fully  Constructed name: %drv%%pth%%fname%%ext%
@ENDLOCAL
pause
7
Jool

Versuchen Sie, unter Beispiel auszuführen, um zu sehen, wie die magischen Variablen funktionieren.

@echo off

SETLOCAL EnableDelayedExpansion

echo Full path and filename: %~f0
echo Drive: %~d0
echo Path: %~p0
echo Drive and path: %~dp0
echo Filename without extension: %~n0
echo Filename with    extension: %~nx0
echo Extension: %~x0

echo date time : %~t0
echo file size: %~z0

ENDLOCAL

Die verwandten Regeln sind folgende.

%~I         - expands %I removing any surrounding quotes ("")
%~fI        - expands %I to a fully qualified path name
%~dI        - expands %I to a drive letter only
%~pI        - expands %I to a path only
%~nI        - expands %I to a file name only
%~xI        - expands %I to a file extension only
%~sI        - expanded path contains short names only
%~aI        - expands %I to file attributes of file
%~tI        - expands %I to date/time of file
%~zI        - expands %I to size of file
%~$PATH:I   - searches the directories listed in the PATH
               environment variable and expands %I to the
               fully qualified name of the first one found.
               If the environment variable name is not
               defined or the file is not found by the
               search, then this modifier expands to the
               empty string
2
Cary

Unten ist mein Anfangscode:

@echo off
Set z=%%
echo.
echo %z%0.......%0
echo %z%~0......%~0
echo %z%n0......%n0
echo %z%x0......%x0
echo %z%~n0.....%~n0
echo %z%dp0.....%dp0
echo %z%~dp0....%~dp0
echo.

Ich habe festgestellt, dass der Dateiname, der durch% ~ 0 und% 0 angegeben wird, der Art und Weise entspricht, in der er in die Befehls-Shell eingegeben wurde, und nicht wie diese Datei tatsächlich benannt wird. Wenn Sie den literalen Fall für den Dateinamen verwenden möchten, sollten Sie% ~ n0 verwenden. Dadurch wird jedoch die Dateierweiterung ausgelassen. Wenn Sie jedoch den Dateinamen kennen, können Sie den folgenden Code hinzufügen. 

set b=%~0
echo %~n0%b:~8,4%

Ich habe gelernt, dass ": ~ 8,4%" am 9. Zeichen der Variablen beginnt und dann die nächsten 4 Zeichen anzeigen. Der Bereich reicht von 0 bis zum Ende der Variablenzeichenfolge. % Path% wäre also sehr lang!

fIlEnAmE.bat
012345678901

Dies ist jedoch nicht so gut wie bei der Lösung von Jool (% ~ x0) oben. 

Meine Beweise:

C:\bin>filename.bat

%0.......filename.bat
%~0......filename.bat
. . .

C:\bin>fIlEnAmE.bat

%0.......fIlEnAmE.bat
%~0......fIlEnAmE.bat
%n0......n0
%x0......x0
%~n0.....FileName
%dp0.....dp0
%~dp0....C:\bin\

%~n0%b:~8,4%...FileName.bat

Press any key to continue . . .

C:\bin>dir
 Volume in drive C has no label.
 Volume Serial Number is CE18-5BD0

 Directory of C:\bin
. . .
05/02/2018  11:22 PM               208 FileName.bat

Hier ist der endgültige Code

@echo off
Set z=%%
set b=%~0
echo.
echo %z%0.......%0
echo %z%~0......%~0
echo %z%n0......%n0
echo %z%x0......%x0
echo %z%~n0.....%~n0
echo %z%dp0.....%dp0
echo %z%~dp0....%~dp0
echo.
echo A complex solution:
echo ===================================
echo %z%~n0%z%b:~8,4%z%...%~n0%b:~8,4%
echo ===================================
echo.
echo The preferred solution:
echo ===================================
echo %z%~n0%z%~x0.......%~n0%~x0
echo ===================================
pause
0
Fred Tusing