Liste der übergebenen Argumente im Batch-Skript von Windows abrufen (.bat)

%* enthält scheinbar alle an das Skript übergebenen Argumente.

%1 ... %n und %* enthalten die Argumente, es kann jedoch schwierig sein, auf sie zuzugreifen, da der Inhalt interpretiert wird.
Deshalb ist es unmöglich, mit normalen Anweisungen so etwas zu behandeln

myBatch.bat "&"^&

Jede Zeile schlägt fehl, da cmd.exe versucht, eines der Et-Zeichen (der Inhalt von% 1 ist "&"&) auszuführen.

set var=%1
set "var=%1"
set var=%~1
set "var=%~1"

Es gibt jedoch eine Problemumgehung mit einer temporären Datei

@echo off
SETLOCAL DisableDelayedExpansion

SETLOCAL
for %%a in (1) do (
    set "Prompt=$_"
    echo on
    for %%b in (1) do rem * #%1#
    @echo off
) > param.txt
ENDLOCAL

for /F "delims=" %%L in (param.txt) do (
  set "param1=%%L"
)
SETLOCAL EnableDelayedExpansion
set "param1=!param1:*#=!"
set "param1=!param1:~0,-2!"
echo %%1 is '!param1!'

Der Trick besteht darin, echo on zu aktivieren und den %1 nach einer rem-Anweisung zu erweitern (funktioniert auch mit% 2 ..% *).
Um die Ausgabe von echo on umleiten zu können, benötigen Sie die beiden FOR-LOOPS. 

Die zusätzlichen Zeichen * # werden verwendet, um vor Inhalten wie /? geschützt zu sein (würde die Hilfe für REM anzeigen).
Oder ein Caret am Zeilenende könnte als mehrzeiliger Charakter wirken. 

Das FOR/F sollte mit verzögerter Erweiterung aus arbeiten, sonst Inhalte mit "!" würde zerstört werden.
Nachdem Sie die zusätzlichen Zeichen in param1 entfernt haben, haben Sie es erhalten. 

Um param1 auf sichere Weise zu verwenden, aktivieren Sie die verzögerte Erweiterung.

Bearbeiten: Eine Bemerkung zu% 0

%0 enthält den Befehl, der zum Aufrufen des Stapels verwendet wird, und bewahrt außerdem den Fall wie in FoO.BaT.
Aber nach einem Aufruf einer Funktion enthält %0 und auch in %~0 den Funktionsnamen (oder besser die Zeichenfolge, mit der die Funktion aufgerufen wurde).
Mit %~f0 können Sie jedoch den Dateinamen abrufen.

@echo off
echo main %0, %~0, %~f0
call :myLabel+xyz
exit /b

:MYlabel
echo func %0, %~0, %~f0
exit /b

Ausgabe

main test.bat, test.bat, C:\temp\test.bat
func :myLabel+xyz, :myLabel+xyz, C:\temp\test.bat

Ich habe das nächste Mal gefunden, wenn Sie diese Informationen nachschlagen müssen. Anstatt einen Browser zu öffnen und ihn zu googeln, könnten Sie einfach call /? in Ihre cmd eingeben und Sie werden es bekommen:

...

%* in a batch script refers to all the arguments (e.g. %1 %2 %3
    %4 %5 ...)

Substitution of batch parameters (%n) has been enhanced.  You can
now use the following optional syntax:

    %~1         - expands %1 removing any surrounding quotes (")
    %~f1        - expands %1 to a fully qualified path name
    %~d1        - expands %1 to a drive letter only
    %~p1        - expands %1 to a path only
    %~n1        - expands %1 to a file name only
    %~x1        - expands %1 to a file extension only
    %~s1        - expanded path contains short names only
    %~a1        - expands %1 to file attributes
    %~t1        - expands %1 to date/time of file
    %~z1        - expands %1 to size of file
    %~$PATH:1   - searches the directories listed in the PATH
                   environment variable and expands %1 to the fully
                   qualified name of the first one found.  If the
                   environment variable name is not defined or the
                   file is not found by the search, then this
                   modifier expands to the empty string

The modifiers can be combined to get compound results:

    %~dp1       - expands %1 to a drive letter and path only
    %~nx1       - expands %1 to a file name and extension only
    %~dp$PATH:1 - searches the directories listed in the PATH
                   environment variable for %1 and expands to the
                   drive letter and path of the first one found.
    %~ftza1     - expands %1 to a DIR like output line

In the above examples %1 and PATH can be replaced by other
valid values.  The %~ syntax is terminated by a valid argument
number.  The %~ modifiers may not be used with %*

So können Sie alle Argumente zu einem Skript abrufen:

@ECHO off
ECHO The %~nx0 script args are...
for %%I IN (%*) DO ECHO %%I
pause

Hier ist eine recht einfache Methode, um die Argumente abzurufen und sie als Umgebungsvariable festzulegen. In diesem Beispiel werde ich sie nur als Schlüssel und Werte bezeichnen.

Speichern Sie das folgende Codebeispiel als "args.bat". Rufen Sie dann die Batchdatei auf. Sie werden von einer Befehlszeile aus gespeichert Beispiel: arg.bat --x 90 --y 120

Ich habe einige Echo-Befehle bereitgestellt, um Sie durch den Prozess zu führen. Das Endergebnis von .__ ist jedoch, dass --x einen Wert von 90 und --y einen Wert von 120 haben wird (dh, wenn Sie das Beispiel wie oben beschrieben ausführen ;-)).

Sie können dann die Bedingungsanweisung 'if defined' verwenden, um zu bestimmen, ob der Codeblock ausgeführt werden soll oder nicht "arg.bat --x hallo-world" Ich könnte dann die Anweisung "IF DEFINED --x echo% - x%" verwenden und das Ergebnis wäre "hallo-world". Es sollte sinnvoller sein, wenn Sie den Batch ausführen.

@setlocal enableextensions enabledelayedexpansion
@ECHO off
ECHO.
ECHO :::::::::::::::::::::::::: arg.bat example :::::::::::::::::::::::::::::::
ECHO :: By:      User2631477, 2013-07-29                                   ::
ECHO :: Version: 1.0                                                         ::
ECHO :: Purpose: Checks the args passed to the batch.                        ::
ECHO ::                                                                      ::
ECHO :: Start by gathering all the args with the %%* in a for loop.          ::
ECHO ::                                                                      ::
ECHO :: Now we use a 'for' loop to search for our keys which are identified  ::
ECHO :: by the text '--'. The function then sets the --arg ^= to the next    ::
ECHO :: arg. "CALL:Function_GetValue" ^<search for --^> ^<each arg^>         ::
ECHO ::                                                                      ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

ECHO.

ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO :: From the command line you could pass... arg.bat --x 90 --y 220       ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
ECHO.Checking Args:"%*"

FOR %%a IN (%*) do (
    CALL:Function_GetValue "--","%%a" 
)

ECHO.
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO :: Now lets check which args were set to variables...                   ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO :: For this we are using the CALL:Function_Show_Defined "--x,--y,--z"   ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
CALL:Function_Show_Defined "--x,--y,--z"
endlocal
goto done

:Function_GetValue

REM First we use find string to locate and search for the text.
echo.%~2 | findstr /C:"%~1" 1>nul

REM Next we check the errorlevel return to see if it contains a key or a value
REM and set the appropriate action.

if not errorlevel 1 (
  SET KEY=%~2
) ELSE (
  SET VALUE=%~2
)
IF DEFINED VALUE (
    SET %KEY%=%~2
    ECHO.
    ECHO ::::::::::::::::::::::::: %~0 ::::::::::::::::::::::::::::::
    ECHO :: The KEY:'%KEY%' is now set to the VALUE:'%VALUE%'                     ::
    ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
    ECHO.
    ECHO %KEY%=%~2
    ECHO.
    REM It's important to clear the definitions for the key and value in order to
    REM search for the next key value set.
    SET KEY=
    SET VALUE=
)
GOTO:EOF

:Function_Show_Defined 
ECHO.
ECHO ::::::::::::::::::: %~0 ::::::::::::::::::::::::::::::::
ECHO :: Checks which args were defined i.e. %~2
ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
SET ARGS=%~1
for %%s in (%ARGS%) DO (
    ECHO.
    ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
    ECHO :: For the ARG: '%%s'                         
    IF DEFINED %%s (
        ECHO :: Defined as: '%%s=!%%s!'                                             
    ) else (
        ECHO :: Not Defined '%%s' and thus has no value.
    )
    ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
    ECHO.
)
goto:EOF

:done

Der folgende Code simuliert ein Array ('params') - übernimmt die vom Skript empfangenen Parameter und speichert sie in den Variablen params_1 .. params_n, wobei n = params_0 = Anzahl der Elemente des Arrays:

@echo off

rem Storing the program parameters into the array 'params':
rem Delayed expansion is left disabled in order not to interpret "!" in program parameters' values;
rem however, if a parameter is not quoted, special characters in it (like "^", "&", "|") get interpreted at program launch
set /a count=0
:repeat
    set /a count+=1
    set "params_%count%=%~1"
    shift
    if defined params_%count% (
        goto :repeat
    ) else (
        set /a count-=1
    )    
set /a params_0=count

rem Printing the program parameters stored in the array 'params':
rem After the variables params_1 .. params_n are set with the program parameters' values, delayed expansion can
rem be enabled and "!" are not interpreted in the variables params_1 .. params_n values
setlocal enabledelayedexpansion
    for /l %%i in (1,1,!params_0!) do (
        echo params_%%i: "!params_%%i!"
    )
endlocal

pause
goto :eof

Sie können For Commad verwenden, um die Liste der Argumente abzurufen.

Hilfe = For /?

Hilfe = Setlocal /?

Hier ist mein Weg =

@echo off
::For Run Use This = cmd /c ""Args.cmd" Hello USER programming-scientist etc"
setlocal EnableDelayedExpansion
set /a Count=0
for %%I IN (%*) DO (
 Echo Arg_!Count! = %%I
 set /a Count+=1 
)
Echo Count Of Args = !Count!
Endlocal

Benötige keinen Schaltbefehl !!

Viele der oben genannten Informationen führten mich zu weiteren Nachforschungen und letztendlich zu meiner Antwort. Daher wollte ich dazu beitragen, dass ich das, was ich getan habe, in der Hoffnung weiterbringe, dass es jemandem hilft:

• Ich wollte auch verschiedene Variablen an eine Batchdatei übergeben, damit sie innerhalb der Datei verarbeitet werden können.

• Ich war okay, sie mit Anführungszeichen an die Batch-Datei zu übergeben

• Ich möchte, dass sie ähnlich wie unten verarbeitet werden - jedoch mit einer Schleife anstatt manuell zu schreiben:

Also wollte ich das ausführen:

prog_ZipDeleteFiles.bat "_appPath=C:\Services\Logs\PCAP" "_appFile=PCAP*.?"

Und über die Magie von for-Schleifen tun Sie dies innerhalb der Batchdatei:

set "_appPath=C:\Services\Logs\PCAP"
set "_appFile=PCAP*.?"

Das Problem, das ich hatte, ist, dass alle meine Versuche, eine for-Schleife zu verwenden, nicht funktionierten. Das folgende Beispiel:

for /f "tokens* delims= " in %%A (%*) DO (
   set %%A
)

würde einfach tun:

set "_appPath=C:\Services\Logs\PCAP"

und nicht:

set "_appPath=C:\Services\Logs\PCAP"
set "_appFile=PCAP*.?"

auch nach der Einstellung 

SETLOCAL EnableDelayedExpansion

Grund dafür war, dass die for-Schleife die gesamte Zeile gelesen hat und meinen zweiten Parameter %% B während der ersten Iteration der Schleife zugewiesen hat. Da% * für alle Argumente steht, muss nur eine einzige Zeile verarbeitet werden. Daher wird nur ein Durchlauf der for-Schleife ausgeführt. Das ist von Design aus und meine Logik war falsch.

Also hörte ich auf, eine for-Schleife zu verwenden, und vereinfachte, was ich mit if, shift und einer goto-Anweisung versuchte. Ich stimme zu, dass es ein bisschen ein bisschen ist, aber es passt mehr zu meinen Bedürfnissen. Ich kann alle Argumente durchlaufen und dann eine if -Anweisung verwenden, um die Schleife zu verlassen, sobald ich sie alle verarbeitet habe.

Die überzeugende Aussage für das, was ich erreichen wollte:

echo on
:processArguments
:: Process all arguments in the order received
if defined %1 then (
    set %1
    shift
    goto:processArguments
) ELSE (
    echo off 
)

UPDATE - Ich musste stattdessen auf Folgendes ändern: Ich habe alle Umgebungsvariablen verfügbar gemacht, als ich versuchte, auf% 1 zu verweisen und die Shift auf diese Weise zu verwenden:

echo on
shift
:processArguments
:: Process all arguments in the order received
if defined %0 then (
    set %0
    shift
    goto:processArguments
) ELSE (
    echo off 
)

Wenn Sie Parameter in Anführungszeichen haben, die Leerzeichen enthalten, funktioniert %* nicht ordnungsgemäß. Die beste Lösung, die ich gefunden habe, ist eine Schleife, die alle Argumente verknüpft: https://serverfault.com/a/22541

set args=%1
shift
:start
if [%1] == [] goto done
set args=%args% %1
shift
goto start

:done
(use %args% here)

Für die Verwendung der Schleife erhalten Sie alle Argumente und im reinen Stapel:

@echo off && setlocal EnableDelayedExpansion

 set "_cnt=0" && for %%Z in (%*) do ( 
 set "_arg_=%%Z" && set /a "_cnt=!_cnt! + 1" && set "_arg_[!_cnt!]=!_arg_!"
 shift && for /l %%l in (!_cnt! 1 !_cnt!) do echo/ The argument n:%%l is: !_arg_[%%l]!
 )

goto :eof 

Ihr Code ist bereit, etwas mit der Argumentnummer zu tun, wo er benötigt wird, wie ...

 @echo off && setlocal EnableDelayedExpansion

 set "_cnt=0" && for %%Z in (%*) do ( 
 set "_arg_=%%Z" && set /a "_cnt=!_cnt! + 1" && set "_arg_[!_cnt!]=!_arg_!"
 shift 

 )

 run_command !_arg_[1]! !_arg_[2]! !_arg_[2]!> log.txt

 @ echo off 
: start 

 :: Geben Sie Ihren Code hier ein 
 echo. %% 1 ist jetzt:% ~ 1 
 
 if "% ~ 2" NEQ "" (
 shift 
 goto: start 
)